PinePhoneBoy/main.scad

// dependency: https://github.com/revarbat/BOSL
include <BOSL/constants.scad>
use <BOSL/transforms.scad>
use <BOSL/shapes.scad>
use <BOSL/masks.scad>
use <BOSL/sliders.scad>

// DEBUG:
//validation = 1;
//xray = 1;

// EXPORT:
MODEL_HARNESS_LEFT=1;
MODEL_HARNESS_RIGHT=2;
MODEL_HARNESS_TOP=3;
MODEL_HARNESS_SLIDER_FRONT=4;
MODEL_HARNESS_SLIDER_BACK=5;
export=0; // [0:5]
function is_not_export() = is_undef(export) || export == 0;
function is_export() = !is_not_export();
function is_model_strict(m) = is_export() && export == m;
function is_model(m) = is_not_export() || export == m;

function get_phone_size() = [160, 76.7, 10];

module cubi(s, fillet=0, edges=EDGES_ALL) {
    if ($preview) {
        cube(s, center=true);
    } else {
        cuboid(s, fillet=fillet, edges=edges);
    }
}

module phone() {
    s=get_phone_size();
    color("gray")
    cubi(s, fillet=5);
}
module arm() {
    $fn=6;
    s=[210, 55, 50];
    color("SaddleBrown")
    down(s.z/2 + get_phone_size().z/2) cubi(s, fillet=20);
}

module phone_harness() {
    ops=get_phone_size();
    ps=[ops.x+0.2, ops.y+0.2, ops.z+0.2];
    shell_wall=3;
    shell_rim_wall=3;
    rim_edge_thickness=1.2;
    rim_edge_tolerance=0.4;
    expose_back_camera=false;
    screwmount_screw=3;
    harness_divider=[16, 0, 1.3];
    harness_size=[ps.x+shell_wall*2, ps.y+shell_wall*2, ps.z+shell_wall*2];
    rim_size=[harness_size.x+2*shell_rim_wall, harness_size.y+2*shell_rim_wall, 6];
    
    w=shell_wall;
    f=2;
    rf=5;
    hs=harness_size;
    backplane_rim_size=[30, ps.y*0.95, shell_wall/2];
    
    // ==== SHELL ====
    
    module shell() {
        $fn = $preview ? 6 : 30;
        difference() {
            cubi(hs, fillet=f);
            cubi(ps, fillet=f);
        }
        shell_rim();
        shell_screwmounts();
    }
    module shell_rim() {
        $fn = $preview ? 6 : 30;
        w=shell_rim_wall;
        s=rim_size;
        intersection() {
            difference() {
                cubi(s, fillet=rf, edges=EDGES_Z_ALL);
                cubi(ps, fillet=f, edges=EDGES_Z_ALL);
            }
            cubi(s, fillet=1);
        }
        rail_extension=10;
        fwd(hs.y/2) xrot(90) harness_rail(slider_len_front+rail_extension);
        back(hs.y/2) xrot(-90) harness_rail(slider_len_back+rail_extension);
    }
    module shell_rim_edge(thickness, groove, tolerance=rim_edge_tolerance) {
        $fn = $preview ? 6 : 30;
        w=thickness + (groove ? tolerance : 0);
        offset=(groove ? 0 : tolerance/2);
        res=[hs.x+2*(w+offset), hs.y+2*(w+offset), 3];
        resi=[hs.x+2*offset, hs.y+2*offset, res.z+1];
        up(0.0) difference() {
            intersection() {
                cubi(res, fillet=rf, edges=EDGES_Z_ALL);
                cubi(res, fillet=(groove?1:1.5), edges=EDGES_BOTTOM);
            }
            cubi(resi, fillet=rf, edges=EDGES_Z_ALL);
        }
    }
    module foreach_screwmount() {
        for(x = [0:1]) for (y = [0:1]) {
            translate([(-0.5+x)*ps.x, (-0.5+y)*ps.y, -hs.z/2])
            children();
        }
    }
    module shell_screwmounts() {
        $fn = $preview ? 6 : 30;
        r=3;
        foreach_screwmount() {
            cylinder(r=r, h=hs.z);
        }
    }
    module shell_screwmounts_holes() {
        $fn = $preview ? 6 : 30;
        foreach_screwmount() {
            up(w) cylinder(d2=screwmount_screw, d1=screwmount_screw*0.5, h=hs.z+1);
            up(hs.z-1) cylinder(d=screwmount_screw+1.5, h=5);
        }
    }
    module shell_backplane(groove) {
        down(hs.z/2 - shell_wall/6) up(backplane_rim_size.z/2) right(harness_divider.x) scale(groove ? 1.01 : 1) cubi(backplane_rim_size, fillet=5, edges=EDGES_Z_LF);
    }
    
    // ==== SHELL SLIDER AND RAIL ====
    
    rail_angle=36;
    rail_wall=1;
    slider_slop=0.1;
    slider_len_back=hs.x*0.3;
    slider_len_front=hs.x*0.3;
    module harness_slider(l) {
        base=2;
        ss=[l, shell_rim_wall, rim_size.z+rail_wall*2];
        up(ss.y + base) xrot(180) slider(l=ss.x, w=ss.z, h=ss.y, base=base, chamfer=0.9, wall=2, ang=rail_angle, slop=slider_slop, orient=ORIENT_X, align=V_UP);
    }
    module harness_rail(l) {
        sw=2;
        ss=[l, shell_rim_wall, rim_size.z+rail_wall*2];
        rail(l=ss.x, w=ss.z, h=ss.y, chamfer=0.5, ang=rail_angle, orient=ORIENT_X, align=V_UP);
    }
    
    // ==== SHELL CUTOUTS ====
    module shell_cutouts() {
        top_cutout();
        bottom_cutout();
        left_cutout();
        right_cutout();
        front_cutout();
        shell_screwmounts_holes();
    }
    // -- TOP --
    module screen_cutout() {
        s=[138, 69, 100];
        up(s.z/2) cubi(s, fillet=3, edges=EDGES_Z_ALL);
    }
    top_offset=6.5;
    module top_speaker_cutout() {
        s=[3, 12, 100];
        right(ps.x/2 - top_offset) up(s.z/2 - ps.z/3) cubi(s, fillet=1);
    }
    module front_camera_cutout() {
        $fn = $preview ? 6 : 30;
        d=5;
        s=[d, d, 100];
        right(ps.x/2 - top_offset) fwd(11.5) cylinder(d=s.x, h=s.z);
    }
    module leds_cutout() {
        s=[4, 14, 100];
        right(ps.x/2 - top_offset) up(s.z/2 - ps.z/3) back(23) cubi(s, fillet=1);
    }
    module top_cutout() {
        screen_cutout();
        top_speaker_cutout();
        front_camera_cutout();
        leds_cutout();
    }
    
    // -- BOTTOM --
    module back_camera_cutout() {
        s=[13, 25, expose_back_camera ? 100 : 11];
        right(ps.x/2 - 7.5) fwd(ps.y/2 - 23) down(s.z/2 - ps.z/3) cubi(s, fillet=6, edges=EDGES_Z_ALL);
    }
    module bottom_speaker_cutout() {
        s=[8, 49, 100];
        left(ps.x/2 - 13)
        difference() {
            down(s.z/2 - ps.z/3) cubi(s, fillet=1);
            bars=8;
            down(ps.z/2)
            for (i = [0:bars-1]) {
                bs=[s.x+2, 1, 2];
                step=s.y/bars;
                fwd(i*step - s.y/2 + step/2) down(w) cube(bs, center=true);
            }
        }
    }
    module bottom_cutout() {
        back_camera_cutout();
        bottom_speaker_cutout();
    }
    
    // -- RIGHT --
    module headphones_cutout() {
        $fn = $preview ? 10 : 30;
        d=8.8;
        p=[ps.x/2, ps.y/2-24, -0.88];
        h=100;
        translate(p) yrot(90) down(10) cylinder(h=h, d=d);
    }
    module right_cutout() {
        headphones_cutout();
    }
    
    // -- LEFT --
    module usbc_cutout() {
        s=[100, 20, 6];
        left(ps.x/2) down(2) cubi(s, fillet=1);
    }
    module left_cutout() {
        usbc_cutout();
    }
    
    // -- FRONT --
    module buttons_cutout() {
        s=[42, 100, 5];
        fwd(ps.y/2) right(ps.x/2 - 44.5) cubi(s, fillet=1);
    }
    module front_cutout() {
        buttons_cutout();
    }
    
    // ==== MODEL ====
    
    divider=harness_divider;
    module model_harness_left() {
        intersection() {
            intersection() {
                translate(divider) downcube([1000, 1000, 1000]);
                translate(divider) leftcube([1000, 1000, 1000]);
            }
            difference() {
                shell();
                shell_rim_edge(rim_edge_thickness, groove=true, tolerance=rim_edge_tolerance);
                shell_cutouts();
                shell_backplane(groove=true);
            }
        }
    }
    module model_harness_right() {
        intersection() {
            intersection() {
                translate(divider) downcube([1000, 1000, 1000]);
                translate(divider) rightcube([1000, 1000, 1000]);
            }
            difference() {
                shell();
                shell_rim_edge(rim_edge_thickness, groove=true, tolerance=rim_edge_tolerance);
                shell_cutouts();
            }
        }
        shell_backplane(groove=false);
    }
    module model_harness_top() {
        intersection() {
            translate(divider) upcube([1000, 1000, 1000]);
            difference() {
                shell();
                shell_cutouts();
            }
        }
        difference() {
            shell_rim_edge(rim_edge_thickness, groove=false);
            shell_cutouts();
        }
    }
    module model_harness_slider_front() {
        difference() {
            fwd(hs.y/2) xrot(90) harness_slider(slider_len_front);
            front_cutout();
        }
    }
    module model_harness_slider_back() {
        back(hs.y/2) xrot(-90) harness_slider(slider_len_back);
    }
    
    if (is_model(MODEL_HARNESS_LEFT)) model_harness_left();
    if (is_model(MODEL_HARNESS_RIGHT)) model_harness_right();    
    if (is_model(MODEL_HARNESS_TOP)) model_harness_top();
    if (is_model(MODEL_HARNESS_SLIDER_FRONT)) model_harness_slider_front();
    if (is_model(MODEL_HARNESS_SLIDER_BACK)) model_harness_slider_back();
}

module model() {
    phone_harness();
}

if (!is_undef(validation)) {
    intersection() {
        phone();
        model();
    }
} else {
    intersection() {
        if (!is_undef(xray)) {
            span_cube([0,1000*xray], [0,1000*xray], [-1000,1000]);
        }
        union() {
            if (is_not_export()) {
                //phone();
                //arm();
            }
            model();
        }
    }
}